{
  pkgs,
  lib,
  packages',
  ...
}: let
  homeEnv = keyboard: {
    imports = [
      ../../../home-manager/profiles/common.nix

      ../../../home-manager/configuration/graphical-gnome3.nix

      ../../../home-manager/programs/firefox.nix
      ../../../home-manager/programs/libreoffice.nix
      ../../../home-manager/programs/neovim.nix
    ];

    home.keyboard = keyboard;

    home.packages = with pkgs; [
      dia

      rustdesk
    ];
  };
in {
  services.gnome = builtins.mapAttrs (attr: value: lib.mkForce value) {
    gnome-remote-desktop.enable = true;
  };

  services.printing.drivers = lib.mkForce (with packages'; [
    dcpj4110dwDriver
    dcpj4110dwCupswrapper
  ]);

  services.printing.extraConf = ''
    LogLevel debug
  '';

  home-manager.users.steveej = homeEnv {
    layout = "en";
    options = ["nodeadkey"];
    variant = "altgr-intl";
  };

  home-manager.users.elias = homeEnv {
    layout = "de";
    options = [];
    variant = "";
  };

  home-manager.users.justyna =
    lib.attrsets.recursiveUpdate (homeEnv {
      layout = "de";
      options = [];
      variant = "";
    }) {
      services.syncthing.enable = true;
      services.syncthing.tray = true;
    };

  system.stateVersion = "21.11";
}