{ pkgs
, ownLib
, dir
, rebuildarg
, moreargs
, diskId
, gitRoot
, previousDiskId ? ""
}:

let
  mntRootVol="/mnt/${diskId}-root";

in rec {
  diskMount = pkgs.writeScript "script" ''
    #!/usr/bin/env bash
    set -xe
    echo Mounting ${diskId}
    sudo cryptsetup luksOpen ${ownLib.disk.bootLuksDevice diskId} ${ownLib.disk.luksName diskId}
    sleep 1
    sudo vgchange -ay ${ownLib.disk.volumeGroup diskId}
    sudo mkdir -p /mnt
    sudo mkdir ${mntRootVol}
    sudo mount ${ownLib.disk.rootFsDevice diskId} ${mntRootVol}
    sudo mount ${ownLib.disk.rootFsDevice diskId} ${mntRootVol}/nixos/home -o subvol=home
    sudo mount ${ownLib.disk.bootFsDevice diskId} ${mntRootVol}/nixos/boot
  '';

  diskUmount = pkgs.writeScript "script" ''
    #!/usr/bin/env bash
    set -xe
    umount -R ${mntRootVol}
    rmdir ${mntRootVol}
    vgchange -an ${ownLib.disk.volumeGroup diskId}
    cryptsetup luksClose ${ownLib.disk.luksName diskId}
    sync
  '';

  diskInstall = pkgs.writeScript "script" ''
    #!/usr/bin/env bash
    set -xe
    pushd ${gitRoot}/${dir}
    export NIXOS_CONFIG="$PWD"/configuration.nix

    [[ -e "''${NIXOS_CONFIG}" ]]
    [[ -e "${mntRootVol}/nixos" ]]

    sudo -E $SHELL <<EOF
    # 'having $system set breaks nixos-install'
    unset system
    nixos-install --max-jobs 5 --cores 4  --no-root-passwd --root ${mntRootVol}/nixos
    EOF
  '';

  diskPrepare = pkgs.writeScript "script" ''
    #!/usr/bin/env bash
    set -xe

    read -p "Continue to format ${ownLib.disk.bootGrubDevice diskId} (YES/n)?" choice
    case "$choice" in
      YES ) echo "Continuing in 3 seconds..."; sleep 3;;
      n|N ) echo "Exiting..."; exit 0;;
      * ) echo "Exiting..."; exit 1;;
    esac

    # Partition
    sync
    {
    fdisk -w always -W always ${ownLib.disk.bootGrubDevice diskId} <<EOF
    g
    n
    1
   
    +1M
    n
    2
   
    +512M
    n
    3
   
   
    t
    1
    4
    x
    n
    2
    2-${diskId}
    n
    3
    3-${diskId}
    r
    w
    EOF
    } || {
      sync
      partprobe  ${ownLib.disk.bootGrubDevice diskId}
    }

    # Encrypt
    cryptsetup luksFormat ${ownLib.disk.bootLuksDevice diskId} -
    cryptsetup luksOpen ${ownLib.disk.bootLuksDevice diskId} ${ownLib.disk.luksName diskId}

    # LVM
    vgcreate ${ownLib.disk.volumeGroup diskId} ${ownLib.disk.luksPhysicalVolume diskId}
    lvcreate ${ownLib.disk.volumeGroup diskId} -L 2G -n swap
    lvcreate ${ownLib.disk.volumeGroup diskId} -l 100%FREE -n root

    # Filesystem
    mkfs.vfat -F32 ${ownLib.disk.bootFsDevice diskId}
    mkfs.btrfs ${ownLib.disk.rootFsDevice diskId}
    mkswap ${ownLib.disk.swapFsDevice diskId}

    # Subvolume and FS hierharchy
    mkdir -p /mnt
    mkdir ${mntRootVol}
    mount ${ownLib.disk.rootFsDevice diskId} ${mntRootVol}
    btrfs subvolume create ${mntRootVol}/nixos
    btrfs subvolume create ${mntRootVol}/home
    mkdir ${mntRootVol}/nixos/{boot,home}

    ${diskUmount}
  '';

  diskRelabel = pkgs.writeScript "script" ''
    #!/usr/bin/env bash
    set -xe

    read -p "Continue to relabel ${ownLib.disk.bootGrubDevice diskId} (YES/n)?" choice
    case "$choice" in
      YES ) echo "Continuing in 3 seconds..."; sleep 3;;
      n|N ) echo "Exiting..."; exit 0;;
      * ) echo "Exiting..."; exit 1;;
    esac

    sync
    {
    sudo fdisk ${ownLib.disk.bootGrubDevice diskId} <<EOF
    x
    n
    2
    2-${diskId}
    n
    3
    3-${diskId}
    r
    i
    2
    i
    3
    w
    EOF
    } || {
      sync
      sudo partprobe  ${ownLib.disk.bootGrubDevice diskId}
    }


    if test "${previousDiskId}"; then
      sudo cryptsetup luksOpen ${ownLib.disk.bootLuksDevice diskId} ${ownLib.disk.luksName diskId}
      sync
      sleep 1
      if sudo vgs ${previousDiskId}; then
        sudo vgrename ${previousDiskId} ${diskId}
        sudo vgscan
      fi
    fi
    sudo cryptsetup close ${ownLib.disk.luksName diskId}
  '';
}