feat: flakify, gnome3

chore: nix fmt
refactor: split out more home-manager programs
feat: migrate shell as flake devShell
feat: initial flake structure with colmena
feat: migrate elias-e525 to colmena
feat: migrate steveej-t14 with colmena
feat: configure chromium extensions
chore: remove all overlays and package overrides
chore: delete some of _archive
feat: migrate vmd102066
feat: migrate sj-vps-htz0

nix/home-manager/programs/gnome-desktop.nix

@@ -0,0 +1,112 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}: let
+in {
+  services = {
+    gnome-keyring.enable = false;
+    blueman-applet.enable = true;
+    flameshot.enable = true;
+  };
+
+  # TODO: remove this comment once i'm sure everything works
+  # xdg.configFile."autostart/gnome-keyring-ssh.desktop".text = ''
+  #   [Desktop Entry]
+  #   Type=Application
+  #   Hidden=true
+  # '';
+
+  services.gpg-agent.pinentryFlavor = "gnome3";
+
+  # workaround: usually created by 'home.xsession.enabled=true' and i don't use with gnome
+  systemd.user.targets.tray = {
+    Unit = {
+      Description = "Home Manager System Tray";
+      Requires = ["graphical-session-pre.target"];
+    };
+  };
+
+  home.packages = [
+    pkgs.wmctrl
+  ];
+
+  home.sessionVariables.MOZ_ENABLE_WAYLAND = "1";
+
+  dconf.settings = let
+    manualKeybindings = [
+      {
+        binding = "Print";
+        command = "flameshot gui";
+        name = "flameshot";
+      }
+
+      {
+        binding = "<Super>t";
+        command = "alacritty";
+        name = "alacritty";
+      }
+    ];
+
+    numWorkspaces = 10;
+    customKeybindingBaseName = "org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom";
+    customKeybindingsNames =
+      builtins.genList (i: "/${customKeybindingBaseName}${toString i}/")
+      (
+        (builtins.length manualKeybindings)
+        + numWorkspaces # for sending to the workspace
+      );
+
+    workspacesKeyBindingsOffset = builtins.length manualKeybindings;
+
+    # with this we can make use of all number keys [0-9]
+    mapToNumber = i:
+      if i < 10
+      then i
+      else if i == 10
+      then 0
+      else throw "i exceeds 10: ${i}";
+  in
+    {
+      "org/gnome/settings-daemon/plugins/media-keys" = {
+        custom-keybindings = customKeybindingsNames;
+        screenreader = "@as []";
+        screensaver = ["<Alt><Super>l"];
+      };
+
+      # disable the builtin <Super>[1-9] functionality
+      "org/gnome/shell/keybindings" = builtins.listToAttrs (builtins.genList
+        (i: {
+          name = "switch-to-application-${toString (i + 1)}";
+          value = [];
+        })
+        numWorkspaces);
+
+      # remap it to switching to the workspaces
+      "org/gnome/desktop/wm/keybindings" = builtins.listToAttrs (builtins.genList
+        (i: {
+          name = "switch-to-workspace-${toString (i + 1)}";
+          value = [
+            "<Super>${toString (mapToNumber (i + 1))}"
+          ];
+        })
+        numWorkspaces);
+    }
+    // builtins.listToAttrs (builtins.genList
+      (i: {
+        name = "${customKeybindingBaseName}${toString i}";
+        value = builtins.elemAt manualKeybindings i;
+      })
+      (builtins.length manualKeybindings))
+    // builtins.listToAttrs (builtins.genList
+      (i: {
+        name = "${customKeybindingBaseName}${toString (workspacesKeyBindingsOffset + i)}";
+        value = {
+          binding = "<Control><Super>${toString (mapToNumber (i + 1))}";
+          command = "wmctrl -r :ACTIVE: -t ${toString i}";
+          name = "Send to workspace ${toString (i + 1)}";
+        };
+      })
+      numWorkspaces);
+}