infra/nix/pkgs/default.nix

{ pkgs }:
let

in rec {
  nixpkgs-master = import <nixpkgs-master> {};

  linuxPackages_sgx_540rc3 = let
      linux_sgx_pkg = { fetchurl, buildLinux, ... } @ args:

        buildLinux (args // rec {
          version = "5.4.0-rc3";
          modDirVersion = version;

          src = fetchurl {
            url = "https://github.com/jsakkine-intel/linux-sgx/archive/v23.tar.gz";
            sha256 = "11rwlwv7s071ia889dk1dgrxprxiwgi7djhg47vi56dj81jgib20";
          };
          kernelPatches = [];

          extraConfig = ''
            INTEL_SGX y
          '';

          extraMeta.branch = "5.4";
        } // (args.argsOverride or {}));
      linux_sgx = pkgs.callPackage linux_sgx_pkg {};
    in
      pkgs.recurseIntoAttrs (pkgs.linuxPackagesFor linux_sgx);
  linuxPackages_sgx_latest = linuxPackages_sgx_540rc3;

  busyboxStatic =  pkgs.busybox.override {
    enableStatic = true;
    extraConfig = ''
       CONFIG_STATIC y
       CONFIG_INSTALL_APPLET_DONT y
       CONFIG_INSTALL_APPLET_SYMLINKS n
     '';
  };
  dropbearStatic = pkgs.dropbear.override {
    enableStatic = true;
  };

  php5 = let
    nixpkgsWithPhp5 = pkgs.fetchFromGitHub {
      owner = "nixos";
      repo = "nixpkgs-channels";
      rev = "846d8f8305192dcc3a63139102698b4ac6b9ef9f";
      sha256 = "1qifgc1q2i4g0ivpfjnxp4jl2cc82gfjws08dsllgw7q7kw4b4rb";
    };
    php5 = (pkgs.callPackage "${nixpkgsWithPhp5}/pkgs/development/interpreters/php/default.nix" {
      config = (pkgs.lib.attrsets.recursiveUpdate
        pkgs.config
        {
          php = {
            imap = false;
            openssl = false;
            curl = false;
            ldap = false;
            mcrypt = false;
          };
        }
      );
      stdenv = pkgs.llvmPackages_6.stdenv; #broken
      icu = pkgs.icu60;
    }).php56;
  in
    php5
    .overrideAttrs(attrs: rec {
      # See https://secure.php.net/ChangeLog-5.php
      version = "5.6.40";
      name = "php-${version}";

      sha256 = "005s7w167dypl41wlrf51niryvwy1hfv53zxyyr3lm938v9jbl7z";
      src = pkgs.fetchurl {
        url = "http://www.php.net/distributions/php-${version}.tar.bz2";
        inherit sha256;
      };

      configureFlags = attrs.configureFlags ++ [
        "--without-fpm-systemd"
      ];

      meta.license = null;
    });

  duplicacy = pkgs.callPackage ../pkgs/duplicacy {};
  mfcl3770cdw = pkgs.callPackage ../pkgs/mfcl3770cdw.nix {};
  staruml = pkgs.callPackage ../pkgs/staruml.nix { inherit (pkgs.gnome2) GConf; libgcrypt = pkgs.libgcrypt_1_5; };

  pythonPackages = myPython;
  myPython = pkgs.python310.withPackages (ps: with ps; [
    pep8 yapf flake8
    # autopep8 (broken)
    # pylint (broken)
    ipython
    llfuse
    dugong
    defusedxml
    wheel
    pip
    virtualenv
    cffi
    pyopenssl
    urllib3
    # mistune (insecure)
    sympy

    flask

    pyaml
  ] ++ [
    pkgs.pypi2nix
    pkgs.libffi
  ]);
}