infra/nix/overlays/overrides.nix

# This overlay is used for overriding upstream packages.

self: super:

let
  nixpkgs-master = import <nixpkgs-master> { inherit (super) config; };

in {
  inherit nixpkgs-master;

  # alacritty = nixpkgs-master.alacritty;
  alacritty = super.stdenv.mkDerivation {
    name = "alacritty-custom";
    buildInputs = [ super.makeWrapper ];
    phases = "installPhase";
    installPhase = ''
      makeWrapper ${self.nixpkgs-master.alacritty}/bin/alacritty $out/bin/alacritty \
        --set-default WINIT_X11_SCALE_FACTOR 1.4
    '';
  };

  roxterm = super.stdenv.mkDerivation {
    name = "roxterm-custom";
    buildInputs = [ super.makeWrapper ];
    phases = "installPhase";
    installPhase = ''
      makeWrapper ${super.roxterm}/bin/roxterm $out/bin/roxterm \
        --add-flags "--separate"
    '';
  };

  # TODO: facetimehd is currfently broken (https://github.com/NixOS/nixpkgs/pull/72804)
  facetimehd-firmware = super.hello;

  qtile = self.nixpkgs-master.qtile.overrideAttrs(oldAttrs: {
    pythonPath = oldAttrs.pythonPath ++ (with self.python37Packages; [
      psutil
      dbus-python
      pyxdg
      mpd2
      # python-wifi
      # iwlib
      dateutil
      keyring
    ]);
  });
}