infra/nix/os/devices/steveej-x13s/flake.nix

{
  inputs =
    {
      nixpkgs.url = "github:nixos/nixpkgs/nixos-23.11";

      # required for home-manager modules
      nixpkgs-unstable-small.url = "github:nixos/nixpkgs/nixos-unstable-small";
      nixpkgs-2211.url = "github:nixos/nixpkgs/nixos-22.11";

      get-flake.url = "github:ursi/get-flake";

      disko.inputs.nixpkgs.follows = "nixpkgs";

      mobile-nixos.url = "github:NixOS/mobile-nixos";
      mobile-nixos.flake = false;

      home-manager = {
        url = "github:nix-community/home-manager/release-23.11";
        inputs.nixpkgs.follows = "nixpkgs";
      };

      nixos-x13s.url = "git+https://codeberg.org/adamcstephens/nixos-x13s";
      nixos-x13s.inputs.nixpkgs.follows = "nixpkgs";
    };

  outputs =
    { self
    , get-flake
    , nixpkgs
    , ...
    }:
    let
      targetPlatform = "aarch64-linux";
      buildPlatform = "x86_64-linux";
      repoFlake = get-flake ../../../..;

      mkNixosConfiguration = { nodeName, extraModules ? [ ], ... } @ attrs:
        nixpkgs.lib.nixosSystem (
          nixpkgs.lib.attrsets.recursiveUpdate
            attrs
            {
              specialArgs = (import ./default.nix {
                system = targetPlatform;
                inherit nodeName repoFlake;

                nodeFlake = self;
              }).meta.nodeSpecialArgs.${nodeName};

              modules =
                [
                  # repoFlake.nixosModules.hardware-x13s
                ]
                ++ extraModules;
            }
        );
    in
    {
      lib = {
        inherit mkNixosConfiguration;
      };

      nixosConfigurations =
        let
          nodeName = "steveej-x13s";
        in
        {
          native = mkNixosConfiguration {
            inherit nodeName;
            system = targetPlatform;
            extraModules = [
              ./configuration.nix
            ];
          };

          cross = mkNixosConfiguration {
            inherit nodeName;
            extraModules = [
              ./configuration.nix

              {
                nixpkgs.buildPlatform.system = buildPlatform;
                nixpkgs.hostPlatform.system = targetPlatform;
              }
            ];
          };
        };
    };
}